feat: implement pytest_test rule

.bazelversion

@@ -1 +1 @@
-9.x
+9.1.1

AGENTS.md

@@ -121,7 +121,6 @@ The `repository_ctx` API docs are at: https://bazel.build/rules/lib/builtins/rep
     e.g. given `load("//foo:bar.bzl", ...)`, the target is `//foo:bar_bzl`.
   * For files outside rules_python: remove the `.bzl` suffix. e.g. given
     `load("@foo//foo:bar.bzl", ...)`, the target is `@foo//foo:bar`.
-* `bzl_library()` targets should be kept in alphabetical order by name.
 
 Example:
 

MODULE.bazel

@@ -214,7 +214,7 @@ dev_pip.parse(
     python_version = "3.11",
     requirements_lock = "//tests/multi_pypi/beta:requirements.txt",
 )
-use_repo(dev_pip, "dev_pip", "pypi_alpha", "pypi_beta", "pypiserver")
+use_repo(dev_pip, "dev_pip", "pypi", "pypi_alpha", "pypi_beta", "pypiserver")
 
 # Bazel integration test setup below
 

docs/BUILD.bazel

@@ -198,6 +198,7 @@ sphinx_build_binary(
     target_compatible_with = _TARGET_COMPATIBLE_WITH,
     deps = [
         "@dev_pip//myst_parser",
+        "@dev_pip//pytest",
         "@dev_pip//readthedocs_sphinx_ext",
         "@dev_pip//sphinx",
         "@dev_pip//sphinx_autodoc2",

docs/pyproject.toml

@@ -17,4 +17,6 @@ dependencies = [
     "pyelftools",
     "macholib",
     "markupsafe",
+    "pytest",
+    "pytest-bazel",
 ]

news/pytest_test.added.md

@@ -0,0 +1,2 @@
+(pytest) Added `pytest_test` macro to run pytest tests using `pytest-bazel`
+from PyPI.

python/BUILD.bazel

@@ -411,6 +411,11 @@ alias(
     deprecation = "Use //python:py_test instead",
 )
 
+bzl_library(
+    name = "pytest_test",
+    deps = ["//python/private/pytest_test"],
+)
+
 alias(
     name = "python_bzl",
     actual = ":python",

python/features.bzl

@@ -122,6 +122,7 @@ _TARGETS = {
     "//python:py_runtime_info": True,
     "//python:py_runtime_pair": True,
     "//python:py_test": True,
+    "//python:pytest_test": True,
     "//python:repositories": True,
     "//python:versions": True,
 }

python/private/pytest_test/BUILD.bazel

@@ -0,0 +1,27 @@
+load("@bazel_skylib//:bzl_library.bzl", "bzl_library")
+
+package(default_visibility = ["//:__subpackages__"])
+
+filegroup(
+    name = "bootstrap_template",
+    srcs = ["pytest_bootstrap_template.py"],
+)
+
+bzl_library(
+    name = "pytest_test",
+    deps = [
+        "//python:py_test",
+    ],
+)
+
+# These aliases are used to avoid duplicate targets in the deps list
+alias(
+    name = "default_pytest",
+    actual = "@pypi//pytest",
+)
+
+# These aliases are used to avoid duplicate targets in the deps list
+alias(
+    name = "default_pytest_bazel",
+    actual = "@pypi//pytest_bazel",
+)

python/private/pytest_test/pytest_bootstrap_template.py

@@ -0,0 +1,8 @@
+import sys
+
+import pytest_bazel
+
+TEST_FILES = """%TEST_FILES%""".splitlines()
+
+args = sys.argv[1:] + TEST_FILES
+sys.exit(pytest_bazel.main(args))

python/private/pytest_test/pytest_test.bzl

@@ -0,0 +1,84 @@
+"""pytest_test rule implementation."""
+
+load("//python:py_test.bzl", "py_test")
+
+_DEFAULT_PYTEST = Label("//python/private/pytest_test:default_pytest")
+_DEFAULT_PYTEST_BAZEL = Label("//python/private/pytest_test:default_pytest_bazel")
+
+def pytest_test(
+        *,
+        name,
+        srcs,
+        pytest = None,
+        pytest_bazel = None,
+        **kwargs):
+    """Run pytest tests.
+
+    Args:
+        name: A unique name for this target.
+        srcs: List of source files (test files). These are the files that
+            pytest will run as tests.
+        pytest: The pytest target to use. Defaults to @pypi//pytest.
+        pytest_bazel: The pytest-bazel target to use. Defaults to
+            @pypi//pytest_bazel.
+        **kwargs: Additional arguments passed to py_test. Note that `main` is
+            not a supported argument.
+    """
+    if pytest == None:
+        pytest = _DEFAULT_PYTEST
+    if pytest_bazel == None:
+        pytest_bazel = _DEFAULT_PYTEST_BAZEL
+
+    bootstrap_target = name + "_bootstrap"
+    main_file = name + "_boot.py"
+    _write_pytest_bootstrap(
+        name = bootstrap_target,
+        srcs = srcs,
+        output_name = main_file,
+    )
+
+    py_test(
+        name = name,
+        main = main_file,
+        srcs = [bootstrap_target] + srcs,
+        deps = kwargs.pop("deps", []) + [
+            pytest,
+            pytest_bazel,
+        ],
+        **kwargs
+    )
+
+def _map_file(f):
+    return f.short_path
+
+def _write_pytest_bootstrap_impl(ctx):
+    output = ctx.actions.declare_file(ctx.attr.output_name)
+
+    computed_subs = ctx.actions.template_dict()
+
+    computed_subs.add_joined(
+        "%TEST_FILES%",
+        depset(ctx.files.srcs),
+        join_with = "\n",
+        map_each = _map_file,
+    )
+
+    ctx.actions.expand_template(
+        output = output,
+        template = ctx.file._bootstrap_template,
+        substitutions = {},
+        computed_substitutions = computed_subs,
+    )
+    return [DefaultInfo(files = depset([output]))]
+
+_write_pytest_bootstrap = rule(
+    implementation = _write_pytest_bootstrap_impl,
+    attrs = {
+        "output_name": attr.string(mandatory = True),
+        "srcs": attr.label_list(allow_files = True),
+        "_bootstrap_template": attr.label(
+            default = "//python/private/pytest_test:bootstrap_template",
+            allow_single_file = True,
+        ),
+    },
+)

python/pytest_test.bzl

@@ -0,0 +1,5 @@
+"""pytest_test rule re-export."""
+
+load("//python/private/pytest_test:pytest_test.bzl", _pytest_test = "pytest_test")
+
+pytest_test = _pytest_test

tests/pytest_test/BUILD.bazel

@@ -0,0 +1,22 @@
+load("//python:pytest_test.bzl", "pytest_test")
+load("//tests/support:support.bzl", "SUPPORTS_BZLMOD")
+
+pytest_test(
+    name = "pytest_script_venv_test",
+    srcs = [
+        "basic_test.py",
+    ],
+    config_settings = {
+        "@rules_python//python/config_settings:bootstrap_impl": "script",
+        "@rules_python//python/config_settings:venvs_site_packages": "yes",
+    },
+    target_compatible_with = SUPPORTS_BZLMOD,
+)
+
+pytest_test(
+    name = "pytest_default_test",
+    srcs = [
+        "basic_test.py",
+    ],
+    target_compatible_with = SUPPORTS_BZLMOD,
+)

tests/pytest_test/basic_test.py

@@ -0,0 +1,2 @@
+def test_foo():
+    assert True